Build: Convert fvp_sse300 target to modern cmake
Add cmake files to mps2/fvp_sse300 target directory. Alter scatter files to
remove preprocessor shebang. Alter header files where include paths have
changed.
WARNING: This change will not build in isolation, it requires _all_
other cmake changes to successfully build. It is split out only for ease
of understanding.
Signed-off-by: Marton Berke <marton.berke@arm.com>
Signed-off-by: Anton Komlev <anton.komlev@arm.com>
Change-Id: I18158967fb1dff1e7adf4f4ac8ea003989ff717a
diff --git a/platform/ext/fvp_sse300_mps2.cmake b/platform/ext/fvp_sse300_mps2.cmake
deleted file mode 100644
index 6117b71..0000000
--- a/platform/ext/fvp_sse300_mps2.cmake
+++ /dev/null
@@ -1,207 +0,0 @@
-#-------------------------------------------------------------------------------
-# Copyright (c) 2019-2020, Arm Limited. All rights reserved.
-# Copyright (c) 2020, Cypress Semiconductor Corporation. All rights reserved.
-#
-# SPDX-License-Identifier: BSD-3-Clause
-#
-#-------------------------------------------------------------------------------
-
-#This file gathers all fvp_sse300_mps2 specific files in the application.
-
-#sse300 has a v8.1-M.Main processor
-include("Common/CpuArmv81mml")
-
-set(PLATFORM_DIR ${CMAKE_CURRENT_LIST_DIR})
-
-set(FVP_SSE300_DIR ${PLATFORM_DIR}/target/mps2/fvp_sse300)
-
-#Specify the location of platform specific build dependencies.
-#FIXME use CMAKE_C_COMPILER_ID here instead?
-if(COMPILER STREQUAL "ARMCLANG")
- set (S_SCATTER_FILE_NAME "${PLATFORM_DIR}/common/armclang/tfm_common_s.sct")
- set (BL2_SCATTER_FILE_NAME "${FVP_SSE300_DIR}/device/source/armclang/fvp_sse300_mps2_bl2.sct")
- set (NS_SCATTER_FILE_NAME "${FVP_SSE300_DIR}/device/source/armclang/fvp_sse300_mps2_ns.sct")
- if (DEFINED CMSIS_DIR)
- # not all project defines CMSIS_DIR, only the ones that use it.
- set (RTX_LIB_PATH "${CMSIS_DIR}/RTOS2/RTX/Library/ARM/RTX_V8MMN.lib")
- endif()
-elseif(COMPILER STREQUAL "GNUARM")
- message(FATAL_ERROR "No GNUARM support yet for target '${TARGET_PLATFORM}'.")
-elseif(COMPILER STREQUAL "IARARM")
- set (S_SCATTER_FILE_NAME "${PLATFORM_DIR}/common/iar/tfm_common_s.icf")
- set (BL2_SCATTER_FILE_NAME "${FVP_SSE300_DIR}/device/source/iar/fvp_sse300_mps2_bl2.icf")
- set (NS_SCATTER_FILE_NAME "${FVP_SSE300_DIR}/device/source/iar/fvp_sse300_mps2_ns.icf")
- if (DEFINED CMSIS_DIR)
- # not all project defines CMSIS_DIR, only the ones that use it.
- set (RTX_LIB_PATH "${CMSIS_DIR}/RTOS2/RTX/Library/IAR/RTX_V8MMN.a")
- endif()
-else()
- message(FATAL_ERROR "Invalid compiler specified: '${COMPILER}'.")
-endif()
-set (FLASH_LAYOUT "${FVP_SSE300_DIR}/partition/flash_layout.h")
-set (PLATFORM_LINK_INCLUDES "${FVP_SSE300_DIR}/partition")
-
-if (BL2)
- set (BL2_LINKER_CONFIG ${BL2_SCATTER_FILE_NAME})
- if (${MCUBOOT_UPGRADE_STRATEGY} STREQUAL "RAM_LOADING")
- message(FATAL_ERROR "ERROR: RAM_LOADING upgrade strategy is not supported on target '${TARGET_PLATFORM}'.")
- endif()
- #FixMe: MCUBOOT_SIGN_RSA_LEN can be removed when ROTPK won't be hard coded in platform/ext/common/template/tfm_rotpk.c
- # instead independently loaded from secure code as a blob.
- if (${MCUBOOT_SIGNATURE_TYPE} STREQUAL "RSA-2048")
- add_definitions(-DMCUBOOT_SIGN_RSA_LEN=2048)
- endif()
- if (${MCUBOOT_SIGNATURE_TYPE} STREQUAL "RSA-3072")
- add_definitions(-DMCUBOOT_SIGN_RSA_LEN=3072)
- endif()
-else()
- message(FATAL_ERROR "BL2 is mandatory on target '${TARGET_PLATFORM}'.")
-endif()
-
-embedded_include_directories(PATH "${PLATFORM_DIR}/cmsis" ABSOLUTE)
-embedded_include_directories(PATH "${PLATFORM_DIR}/target/mps2" ABSOLUTE)
-embedded_include_directories(PATH "${PLATFORM_DIR}/../include" ABSOLUTE)
-embedded_include_directories(PATH "${FVP_SSE300_DIR}" ABSOLUTE)
-embedded_include_directories(PATH "${FVP_SSE300_DIR}/partition" ABSOLUTE)
-embedded_include_directories(PATH "${FVP_SSE300_DIR}/device/include" ABSOLUTE)
-embedded_include_directories(PATH "${FVP_SSE300_DIR}/device/config" ABSOLUTE)
-embedded_include_directories(PATH "${FVP_SSE300_DIR}/cmsis_drivers/config" ABSOLUTE)
-embedded_include_directories(PATH "${FVP_SSE300_DIR}/native_drivers" ABSOLUTE)
-
-#Gather all source files we need.
-if (NOT DEFINED BUILD_CMSIS_CORE)
- message(FATAL_ERROR "Configuration variable BUILD_CMSIS_CORE (true|false) is undefined!")
-elseif(BUILD_CMSIS_CORE)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/device/source/system_core_init.c")
-endif()
-
-if (NOT DEFINED BUILD_RETARGET)
- message(FATAL_ERROR "Configuration variable BUILD_RETARGET (true|false) is undefined!")
-elseif(BUILD_RETARGET)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/device/source/device_definition.c")
-endif()
-
-if (NOT DEFINED BUILD_UART_STDOUT)
- message(FATAL_ERROR "Configuration variable BUILD_UART_STDOUT (true|false) is undefined!")
-elseif(BUILD_UART_STDOUT)
- if (NOT DEFINED SECURE_UART1)
- message(FATAL_ERROR "Configuration variable SECURE_UART1 (true|false) is undefined!")
- elseif(SECURE_UART1)
- add_definitions(-DSECURE_UART1)
- endif()
- list(APPEND ALL_SRC_C "${PLATFORM_DIR}/common/uart_stdout.c")
- embedded_include_directories(PATH "${PLATFORM_DIR}/common" ABSOLUTE)
- set(BUILD_NATIVE_DRIVERS true)
- set(BUILD_CMSIS_DRIVERS true)
-endif()
-
-if (NOT DEFINED BUILD_NATIVE_DRIVERS)
- message(FATAL_ERROR "Configuration variable BUILD_NATIVE_DRIVERS (true|false) is undefined!")
-elseif(BUILD_NATIVE_DRIVERS)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/native_drivers/uart_cmsdk_drv.c")
-
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/native_drivers/mpc_sie_drv.c"
- "${FVP_SSE300_DIR}/native_drivers/ppc_sse300_drv.c")
-endif()
-
-if (NOT DEFINED BUILD_TIME)
- message(FATAL_ERROR "Configuration variable BUILD_TIME (true|false) is undefined!")
-elseif(BUILD_TIME)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/native_drivers/systimer_armv8-m_drv.c")
-endif()
-
-if (NOT DEFINED BUILD_STARTUP)
- message(FATAL_ERROR "Configuration variable BUILD_STARTUP (true|false) is undefined!")
-elseif(BUILD_STARTUP)
- if(CMAKE_C_COMPILER_ID STREQUAL "ARMCLANG")
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/device/source/startup_fvp_sse300_mps2_s.c")
- list(APPEND ALL_SRC_C_NS "${FVP_SSE300_DIR}/device/source/startup_fvp_sse300_mps2_ns.c")
- list(APPEND ALL_SRC_C_BL2 "${FVP_SSE300_DIR}/device/source/startup_fvp_sse300_mps2_bl2.c")
- elseif(CMAKE_C_COMPILER_ID STREQUAL "GNUARM")
- message(FATAL_ERROR "No GNUARM support yet for target '${TARGET_PLATFORM}'.")
- elseif(COMPILER STREQUAL "IARARM")
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/device/source/startup_fvp_sse300_mps2_s.c")
- list(APPEND ALL_SRC_C_NS "${FVP_SSE300_DIR}/device/source/startup_fvp_sse300_mps2_ns.c")
- list(APPEND ALL_SRC_C_BL2 "${FVP_SSE300_DIR}/device/source/startup_fvp_sse300_mps2_bl2.c")
- else()
- message(FATAL_ERROR "No startup file is available for compiler '${CMAKE_C_COMPILER_ID}'.")
- endif()
-endif()
-
-if (NOT DEFINED BUILD_TARGET_CFG)
- message(FATAL_ERROR "Configuration variable BUILD_TARGET_CFG (true|false) is undefined!")
-elseif(BUILD_TARGET_CFG)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/target_cfg.c")
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/spm_hal.c")
- list(APPEND ALL_SRC_C_S "${PLATFORM_DIR}/common/template/attest_hal.c")
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/native_drivers/mpu_armv8m_drv.c")
- if (TFM_PARTITION_PLATFORM)
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/services/src/tfm_platform_system.c")
- endif()
- list(APPEND ALL_SRC_C_S "${PLATFORM_DIR}/common/tfm_hal_its.c")
- list(APPEND ALL_SRC_C_S "${PLATFORM_DIR}/common/tfm_hal_ps.c")
- list(APPEND ALL_SRC_C_S "${PLATFORM_DIR}/common/tfm_platform.c")
- embedded_include_directories(PATH "${PLATFORM_DIR}/common" ABSOLUTE)
-endif()
-
-if (NOT DEFINED BUILD_PLAT_TEST)
- message(FATAL_ERROR "Configuration variable BUILD_PLAT_TEST (true|false) is undefined!")
-elseif(BUILD_PLAT_TEST)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/plat_test.c")
-endif()
-
-if (NOT DEFINED BUILD_BOOT_HAL)
- message(FATAL_ERROR "Configuration variable BUILD_BOOT_HAL (true|false) is undefined!")
-elseif(BUILD_BOOT_HAL)
-
- list(APPEND ALL_SRC_C "${PLATFORM_DIR}/common/boot_hal.c")
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/boot_hal.c")
-endif()
-
-if (NOT DEFINED BUILD_TARGET_HARDWARE_KEYS)
- message(FATAL_ERROR "Configuration variable BUILD_TARGET_HARDWARE_KEYS (true|false) is undefined!")
-elseif(BUILD_TARGET_HARDWARE_KEYS)
- list(APPEND ALL_SRC_C "${PLATFORM_DIR}/common/template/tfm_initial_attestation_key_material.c")
- list(APPEND ALL_SRC_C "${PLATFORM_DIR}/common/template/tfm_rotpk.c")
- list(APPEND ALL_SRC_C "${PLATFORM_DIR}/common/template/crypto_keys.c")
-endif()
-
-if (NOT DEFINED BUILD_TARGET_NV_COUNTERS)
- message(FATAL_ERROR "Configuration variable BUILD_TARGET_NV_COUNTERS (true|false) is undefined!")
-elseif(BUILD_TARGET_NV_COUNTERS)
- # NOTE: This non-volatile counters implementation is a dummy
- # implementation. Platform vendors have to implement the
- # API ONLY if the target has non-volatile counters.
- list(APPEND ALL_SRC_C "${PLATFORM_DIR}/common/template/nv_counters.c")
- set(TARGET_NV_COUNTERS_ENABLE ON)
- # Sets PS_ROLLBACK_PROTECTION flag to compile in the PS services
- # rollback protection code as the target supports nv counters.
- set(PS_ROLLBACK_PROTECTION ON)
-endif()
-
-if (NOT DEFINED BUILD_CMSIS_DRIVERS)
- message(FATAL_ERROR "Configuration variable BUILD_CMSIS_DRIVERS (true|false) is undefined!")
-elseif(BUILD_CMSIS_DRIVERS)
- list(APPEND ALL_SRC_C_S "${FVP_SSE300_DIR}/cmsis_drivers/Driver_MPC.c"
- "${FVP_SSE300_DIR}/cmsis_drivers/Driver_Flash.c"
- "${FVP_SSE300_DIR}/cmsis_drivers/Driver_SSE300_PPC.c")
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/cmsis_drivers/Driver_USART.c")
- embedded_include_directories(PATH "${FVP_SSE300_DIR}/cmsis_drivers" ABSOLUTE)
- embedded_include_directories(PATH "${PLATFORM_DIR}/driver" ABSOLUTE)
-endif()
-
-if (NOT DEFINED BUILD_FLASH)
- message(FATAL_ERROR "Configuration variable BUILD_FLASH (true|false) is undefined!")
-elseif(BUILD_FLASH)
- list(APPEND ALL_SRC_C "${FVP_SSE300_DIR}/cmsis_drivers/Driver_Flash.c")
- # There is no real flash memory for code on MPS2 fvp. Instead data SRAMs are used for code
- # storage: SSRAM2 and SSRAM3. The Driver_Flash driver just emulates a flash interface and behaviour on
- # top of the SRAM memory.
- # As the PS area is going to be in RAM, it is required to set PS_CREATE_FLASH_LAYOUT
- # to be sure the PS service knows that when it starts the PS area does not contain any
- # valid PS flash layout and it needs to create one. The same for ITS.
- set(PS_CREATE_FLASH_LAYOUT ON)
- set(ITS_CREATE_FLASH_LAYOUT ON)
- embedded_include_directories(PATH "${FVP_SSE300_DIR}/cmsis_drivers" ABSOLUTE)
- embedded_include_directories(PATH "${PLATFORM_DIR}/driver" ABSOLUTE)
-endif()
diff --git a/platform/ext/target/mps2/fvp_sse300/CMakeLists.txt b/platform/ext/target/mps2/fvp_sse300/CMakeLists.txt
new file mode 100644
index 0000000..cd4d6cb
--- /dev/null
+++ b/platform/ext/target/mps2/fvp_sse300/CMakeLists.txt
@@ -0,0 +1,182 @@
+#-------------------------------------------------------------------------------
+# Copyright (c) 2020, Arm Limited. All rights reserved.
+#
+# SPDX-License-Identifier: BSD-3-Clause
+#
+#-------------------------------------------------------------------------------
+
+cmake_policy(SET CMP0076 NEW)
+set(CMAKE_CURRENT_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR})
+
+#========================= Platform region defs ===============================#
+
+target_include_directories(platform_region_defs
+ INTERFACE
+ partition
+)
+
+#========================= Platform common defs ===============================#
+
+if (${CMAKE_C_COMPILER_ID} STREQUAL GNU)
+ message(FATAL_ERROR "gcc is currently not supported on the mps/fvp_sse300 due to a lack of scatter files")
+endif()
+
+# Specify the location of platform specific build dependencies.
+target_sources(tfm_s
+ PRIVATE
+ $<$<C_COMPILER_ID:ARMClang>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/startup_fvp_sse300_mps2_s.c>
+ # $<$<C_COMPILER_ID:GNU>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/startup_fvp_sse300_mps2_s.c>
+)
+target_add_scatter_file(tfm_s
+ $<$<C_COMPILER_ID:ARMClang>:${CMAKE_BINARY_DIR}/generated/platform/ext/common/armclang/tfm_common_s.sct>
+ # $<$<C_COMPILER_ID:GNU>:${CMAKE_BINARY_DIR}/generated/platform/ext/common/gcc/tfm_common_s.ld>
+ $<$<C_COMPILER_ID:IAR>:${CMAKE_BINARY_DIR}/generated/platform/ext/common/iar/tfm_common_s.icf>
+)
+
+if(NS)
+ target_sources(tfm_ns
+ PRIVATE
+ $<$<C_COMPILER_ID:ARMClang>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/startup_fvp_sse300_mps2_ns.c>
+ # $<$<C_COMPILER_ID:GNU>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/startup_fvp_sse300_mps2_ns.c>
+ )
+ target_add_scatter_file(tfm_ns
+ $<$<C_COMPILER_ID:ARMClang>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/armclang/fvp_sse300_mps2_ns.sct>
+ # $<$<C_COMPILER_ID:GNU>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/gcc/fvp_sse300_mps2_ns.ld>
+ )
+ target_link_libraries(tfm_ns
+ PRIVATE
+ $<$<C_COMPILER_ID:ARMClang>:${CMSIS_5_PATH}/RTOS2/RTX/Library/ARM/RTX_V8MBN.lib>
+ # $<$<C_COMPILER_ID:GNU>:${CMSIS_5_PATH}/RTOS2/RTX/Library/GCC/libRTX_V8MBN.a>
+ # These libraries require linking to the veneers, so the veneers are
+ # marked again here as a link dependency to get the ordering right
+ tfm_s_veneers
+ tfm_spm
+ )
+endif()
+
+if(BL2)
+ target_sources(bl2
+ PRIVATE
+ $<$<C_COMPILER_ID:ARMClang>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/startup_fvp_sse300_mps2_bl2.c>
+ # $<$<C_COMPILER_ID:GNU>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/startup_fvp_sse300_mps2_bl2.c>
+ )
+ target_add_scatter_file(bl2
+ $<$<C_COMPILER_ID:ARMClang>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/armclang/fvp_sse300_mps2_bl2.sct>
+ # $<$<C_COMPILER_ID:GNU>:${CMAKE_CURRENT_SOURCE_DIR}/device/source/gcc/fvp_sse300_mps2_bl2.ld>
+ )
+endif()
+
+#========================= Platform Secure ====================================#
+
+target_include_directories(platform_s
+ PUBLIC
+ .
+ ../common
+ cmsis_drivers
+ cmsis_drivers/config
+ device
+ device/config
+ device/include
+ device/source/armclang
+ native_drivers
+ partition
+ services/src
+ native_drivers
+ ${PLATFORM_DIR}/..
+)
+
+target_sources(platform_s
+ PRIVATE
+ device/source/system_core_init.c
+ device/source/device_definition.c
+ native_drivers/uart_cmsdk_drv.c
+ native_drivers/systimer_armv8-m_drv.c
+ target_cfg.c
+ cmsis_drivers/Driver_USART.c
+ cmsis_drivers/Driver_Flash.c
+ native_drivers/mpc_sie_drv.c
+ native_drivers/ppc_sse300_drv.c
+ spm_hal.c
+ native_drivers/mpu_armv8m_drv.c
+ cmsis_drivers/Driver_MPC.c
+ cmsis_drivers/Driver_SSE300_PPC.c
+ $<$<BOOL:TFM_PARTITION_PLATFORM>:${CMAKE_CURRENT_SOURCE_DIR}/plat_test.c>
+ $<$<BOOL:TFM_PARTITION_PLATFORM>:${CMAKE_CURRENT_SOURCE_DIR}/services/src/tfm_platform_system.c>
+)
+
+target_link_libraries(platform_s
+ PRIVATE
+ tfm_utilities
+)
+
+target_compile_options(platform_s
+ PUBLIC
+ ${COMPILER_CMSE_FLAG}
+)
+
+target_compile_definitions(platform_s
+ PUBLIC
+ $<$<C_COMPILER_ID:GNU>:__STARTUP_CLEAR_BSS_MULTIPLE>
+ $<$<C_COMPILER_ID:GNU>:__STARTUP_COPY_MULTIPLE>
+)
+
+#========================= Platform Non-Secure ================================#
+
+target_sources(platform_ns
+ PRIVATE
+ device/source/system_core_init.c
+ device/source/device_definition.c
+ native_drivers/uart_cmsdk_drv.c
+ native_drivers/systimer_armv8-m_drv.c
+ cmsis_drivers/Driver_USART.c
+ cmsis_drivers/Driver_Flash.c
+)
+
+target_include_directories(platform_ns
+ PUBLIC
+ .
+ ${PLATFORM_DIR}/..
+ cmsis_drivers
+ cmsis_drivers/config
+ device
+ device/config
+ device/include
+ device/source/armclang
+ native_drivers
+ partition
+ services/src
+ native_drivers
+)
+
+#========================= Platform BL2 =======================================#
+
+if(BL2)
+ target_sources(platform_bl2
+ PRIVATE
+ boot_hal.c
+ device/source/device_definition.c
+ device/source/system_core_init.c
+ cmsis_drivers/Driver_Flash.c
+ native_drivers/uart_cmsdk_drv.c
+ cmsis_drivers/Driver_USART.c
+ )
+
+ target_include_directories(platform_bl2
+ PUBLIC
+ cmsis_drivers
+ cmsis_drivers/config
+ device
+ device/config
+ device/include
+ device/source/armclang
+ native_drivers
+ partition
+ services/src
+ native_drivers
+
+ PRIVATE
+ .
+ ${PLATFORM_DIR}/..
+ native_drivers
+ )
+endif()
diff --git a/platform/ext/target/mps2/fvp_sse300/config.cmake b/platform/ext/target/mps2/fvp_sse300/config.cmake
new file mode 100644
index 0000000..a81c8a1
--- /dev/null
+++ b/platform/ext/target/mps2/fvp_sse300/config.cmake
@@ -0,0 +1,6 @@
+#-------------------------------------------------------------------------------
+# Copyright (c) 2020, Arm Limited. All rights reserved.
+#
+# SPDX-License-Identifier: BSD-3-Clause
+#
+#-------------------------------------------------------------------------------
diff --git a/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_bl2.sct b/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_bl2.sct
index f15c296..1f6a34a 100644
--- a/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_bl2.sct
+++ b/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_bl2.sct
@@ -1,5 +1,3 @@
-#! armclang --target=arm-arm-none-eabi -march=armv8-m.main -E -xc
-
/*
* Copyright (c) 2017-2020 Arm Limited. All rights reserved.
*
diff --git a/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_ns.sct b/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_ns.sct
index 091c510..92707b9 100644
--- a/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_ns.sct
+++ b/platform/ext/target/mps2/fvp_sse300/device/source/armclang/fvp_sse300_mps2_ns.sct
@@ -1,5 +1,3 @@
-#! armclang --target=arm-arm-none-eabi -march=armv8-m.main -E -xc
-
/*
* Copyright (c) 2017-2020 Arm Limited. All rights reserved.
*
diff --git a/platform/ext/target/mps2/fvp_sse300/preload.cmake b/platform/ext/target/mps2/fvp_sse300/preload.cmake
new file mode 100644
index 0000000..db0a473
--- /dev/null
+++ b/platform/ext/target/mps2/fvp_sse300/preload.cmake
@@ -0,0 +1,19 @@
+#-------------------------------------------------------------------------------
+# Copyright (c) 2020, Arm Limited. All rights reserved.
+#
+# SPDX-License-Identifier: BSD-3-Clause
+#
+#-------------------------------------------------------------------------------
+
+# preload.cmake is used to set things that related to the platform that are both
+# immutable and global, which is to say they should apply to any kind of project
+# that uses this platform. In practise this is normally compiler definitions and
+# variables related to hardware.
+
+# Set architecture and CPU
+set(TFM_SYSTEM_PROCESSOR cortex-m33)
+set(TFM_SYSTEM_ARCHITECTURE armv8-m.main)
+set(TFM_SYSTEM_DSP OFF)
+
+# Reload compiler to generate options from the CPU and architecture
+_compiler_reload()